libc/winsup/configure.in

dnl Autoconf configure script for Cygwin.
dnl Copyright 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003 Red Hat, Inc.
dnl
dnl This file is part of Cygwin.
dnl
dnl This software is a copyrighted work licensed under the terms of the
dnl Cygwin license.  Please consult the file "CYGWIN_LICENSE" for
dnl details.
dnl
dnl Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)dnl
AC_INIT(Makefile.in)

INSTALL=`cd $srcdir/..; echo $(pwd)/install-sh -c`

AC_PROG_INSTALL
AC_CANONICAL_SYSTEM

GCC_NO_EXECUTABLES

LIB_AC_PROG_CC
LIB_AC_PROG_CXX

AC_LANG_C

use_cygserver='yes'
AC_ARG_ENABLE(server,
[ --enable-server		Build a cygwin DLL which can communicate with cygserver],
[case "${enableval}" in
yes)	;;
no)	use_cygserver=;;
esac
])

INSTALL_LICENSE=

case "$target" in
  *cygwin*)
    if ! test -d $srcdir/cygwin; then
      AC_MSG_ERROR("No cygwin dir.  Can't build Cygwin.  Exiting...")
    fi
    AC_CONFIG_SUBDIRS(cygwin)
    INSTALL_LICENSE="install-license"
    ;;
  *mingw*)
    if ! test -d $srcdir/mingw; then
      AC_MSG_ERROR("No mingw dir.  Can't build Mingw.  Exiting...")
    fi
    ;;
esac

if test -d $srcdir/mingw; then
  AC_CONFIG_SUBDIRS(mingw)
fi
AC_CONFIG_SUBDIRS(w32api)

case "$with_cross_host" in
  ""|*cygwin*)
    # if test -d $srcdir/bz2lib; then
    #  AC_CONFIG_SUBDIRS(bz2lib)
    # fi
    # if test -d $srcdir/zlib; then
    #   AC_CONFIG_SUBDIRS(zlib)
    # fi
    if test -d $srcdir/lsaauth; then
      AC_CONFIG_SUBDIRS(lsaauth)
    fi
    if test -n "$use_cygserver" -a -d $srcdir/cygserver; then
      AC_CONFIG_SUBDIRS(cygserver)
    fi
    AC_CONFIG_SUBDIRS(utils doc)
    ;;
esac

AC_SUBST(INSTALL_LICENSE)

AC_PROG_MAKE_SET

AC_OUTPUT(Makefile)